Исправляем синий экран смерти (BSOD). Windows Debugging Tool

Все что связано с работой этой операционной системы

Модератор: Tim308

Ответить
Аватара пользователя

Автор темы
DesignerMix
Администратор
Администратор
Сообщения: 4830
Зарегистрирован: 25 апр 2014, 10:51
Есть ответ: 185
Откуда: Белгород
Контактная информация:
Статус: Не в сети

Исправляем синий экран смерти (BSOD). Windows Debugging Tool

Сообщение DesignerMix » 29 апр 2014, 09:55

Я показал процесс анализа дампов памяти которые создаются при появлении синего экрана смерти (Blue screen of death) при помощи инструментов Windows Debugging Tool и скрипта KDFE (kdfe.cmd). Этот способ помогает выявить именно то устройство, драйвер либо другую проблему которая вызвала BSOD. Надеюсь это видео было вам полезным.

Если у вас есть проблема с анализом дампов памяти, предлагаю заархивировать файлы дампов и прикрепить архив к вашему сообщению в качестве вложения. Я со своей стороны буду их анализировать и указывать вероятную причину появления синего экрана смерти а также то как ее можно исправить.

PS:Напомню что дампы памяти по умолчанию находятся в папке C:\Windows\Minidump


Отредактированный мной скрипт KDFE:

Код: Выделить всё

::=====================================================================
:: Name:           KDFE.CMD
::
:: Purpose:        Kernel debugger Front End.
::
:: Usage:          kdfe.cmd [dump_file] [-v]
::
:: Version:        1.1
::
:: Technology:     Windows Command Script
::
:: Requirements:   Windows 2000+
::                 Debugging Tools for Windows
::                 reg.exe:
::                     Windows XP: built-in
::                     Windows 2000: install Windows Support Tools
::
:: Authors:        Alexander Suhovey (asuhovey@gmail.com)
::=====================================================================
@echo off
setlocal ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
if "%~1"=="-debug" (echo on&set debug=1&shift /1)
set sver=1.1
echo.

::==========================
:: Variables
::==========================

::Kernel debugger path. Default is:

::For version 6.8.4.0 - October 18, 2007 and older
IF EXIST "%PROGRAMFILES(x86)%\Windows Kits\8.0\Debuggers\x64\kd.exe" (
	set dbgpath="%PROGRAMFILES(x86)%\Windows Kits\8.0\Debuggers\x64"
	) ELSE (
		rem For version 6.9.3.113 - April 29, 2008 and newer
		rem 32 bit
		IF EXIST "%PROGRAMFILES%\Windows Kits\8.0\Debuggers\x32\kd.exe" (
			set dbgpath="%PROGRAMFILES%\Windows Kits\8.0\Debuggers\x32"
			) ELSE (
				rem 64 bit
				IF EXIST "%PROGRAMFILES(x86)%\Windows Kits\8.0\Debuggers\x32\kd.exe" (
					set dbgpath="%PROGRAMFILES(x86)%\Windows Kits\8.0\Debuggers\x32"
					) ELSE (
						IF EXIST "%PROGRAMFILES%\Windows Kits\8.0\Debuggers\x64\kd.exe" (
							set dbgpath="%PROGRAMFILES%\Windows Kits\8.0\Debuggers\x64\kd.exe"
							) ELSE (
								echo ERROR: Debugging Tools for Windows not found^^!
								pause
								exit /b 1
							)
					)
			)
	)

:: Or set the path to Debugging Tools below
:: set dbgpath="<path>"

::Symbols and executable images folders. If folders do not contain
:: required files, kd.exe will download them from Microsoft Symbols
:: Server as needed.
set smbpath=%SYSTEMDRIVE%\symbols
set imgpath=%smbpath%

::Microsoft Symbols Server URL.
set smburl=http://msdl.microsoft.com/download/symbols
set imgurl=%smburl%

::Windows Crash Control registry settings path.
set ccregpath="HKLM\SYSTEM\CurrentControlSet\Control\CrashControl"

::Debugger parameters.
set dbgparams=-y srv*"%smbpath:"=%"*%smburl% -i srv*"%imgpath:"=%"*%imgurl% -c
if "%debug%"=="1" (
    set dbgparams=%dbgparams% "^^^!sym noisy; .reload; ^^^!analyze -v; q"
) else (
     set dbgparams=%dbgparams% "^^^!analyze -v; q"
)

::==========================
:: Parse arguments
::==========================
set dumpfile=&set v=&
:PARSE
set arg=%~1&
shift /1
if not defined arg goto NEXT
if defined v (if defined dumpfile goto NEXT)
if "%arg%"=="/?" (goto SYNTAX) else (if "%arg%"=="-?" goto SYNTAX)
if "%arg%"=="-v" (set verbose=1&goto PARSE)
if not defined dumpfile (set dumpfile="%arg%"&goto PARSE)
:NEXT

::==========================
:: Checks
::==========================
set dbgpath=%dbgpath:"=%
for %%i in (reg.exe,"%dbgpath%\kd.exe") do (
    if "%%~$PATH:i"=="" (
        if not exist %%i (
		echo ERROR: Cannot find required file '%%~i'
		pause
		goto :EOF
        )
    )
)

::==========================
:: Main section
::==========================
set /a n=0
if defined dumpfile (
    if exist !dumpfile! (
        for %%z in (!dumpfile!) do (set dumpfile="%%~dpnxz")
        call :ANALYZE !dumpfile! %verbose%
    ) else (
        echo ERROR: Cannot find dump file !dumpfile!
    )
) else (
    for /f "tokens=2*" %%i in ('reg query %ccregpath% /v DumpFile 2^>^&1 ^| find "DumpFile"') do set kdump=%%j
    for /f "tokens=2*" %%k in ('reg query %ccregpath% /v MinidumpDir 2^>^&1 ^| find "MinidumpDir"') do set minidir=%%l
    if "!kdump!!minidir!"=="" echo ERROR: Cannot find required registry information^^!&pause&goto :EOF
    call :ENUMD "!kdump!" "!minidir!"
    if !n!==0 (
        echo No crash dump files found with following search filter:
        echo !kdump!
        echo !minidir!\*.dmp
    ) else (
        echo Following crash dump files found:
        echo.
        for /l %%n in (1,1,!n!) do (call :GETD %%n& echo %%n. !dumpfile!)
        echo. 
        set /p foo="Which one would you like to analyze?[1-!n!] "
        for /l %%s in (1,1,!n!) do (
            if !foo!==%%s (
                call :GETD %%s
                call :ANALYZE !dumpfile! %verbose%
		pause
                goto :EOF
            )
        )
        echo.
        echo What was that? Have some coffee and try again.
    )
)
pause
goto :EOF

::==========================
:: Subroutines
::==========================
:ANALYZE
pushd "%dbgpath%"
if "%2"=="1" (kd.exe -z %1 %dbgparams% 2>&1) else (
    echo.
    set /p bar="Analyzing %1, please wait..."<nul
    for /f "delims=" %%r in ('kd.exe -z %1 %dbgparams% 2^>^&1') do (
        set out=%%r
        if not "!out:PROCESS_NAME:=!"=="!out!" (set process=!out:PROCESS_NAME:  =!)
        if not "!out:BUGCHECK_STR:=!"=="!out!" (set crashcode=!out:BUGCHECK_STR:  =!)
        if not "!out:Debug session=!"=="!out!" (set crashdate=!out:Debug session time: =!)
        if "!out:~0,18!"=="Probably caused by" (set guess=%%r)
    )
    echo  Done.&echo.
    if defined guess (
        echo.
        echo Crash date:         !crashdate!
        echo Stop error code:    !crashcode!
        if defined process echo Process name:       !process!
        echo !guess: :=:!
    ) else (
        echo Didn't find the answer. Try again with '-v' switch.
    ) 
) 
popd
goto :EOF 

:ENUMD
if exist %1 (set /a n+=1&set !n!=%1)
for %%m in ("%~2\*.dmp") do (set /a n+=1&set !n!="%%m")
goto :EOF

:GETD
for /f "tokens=2 delims==" %%o in ('set %1 ^| find "%1="') do (set dumpfile=%%o&goto :EOF)
goto :EOF

:SYNTAX
echo. 
echo Kernel Debugger Front End v%sver%
echo.
echo SYNTAX:
echo.
echo   %~nx0 [dump_file] [-v]
echo.
echo   dump_file  - Crash dump file. If omitted, KDFE will search for crash
echo                dump files in locations configured on your computer and
echo                let you select a file to analyze.
echo   -v         - Verbose output. By default KDFE shows only basic crash
echo                information and debugger's guess about crash cause.
echo                This switch will show full debugger session output.
echo.
echo EXAMPLES:
echo.
echo   %~nx0 "c:\my dumps\memory.dmp" -v
echo.
echo REQUIREMENTS:
echo.
echo   Debugging Tools for Windows
echo.
echo REFERENCES:
echo.
echo Debugging Tools for Windows:
echo   http://www.microsoft.com/whdc/devtools/debugging/default.mspx
echo.
echo Windows Hang and Crash Dump Analysis webcast by Mark Russinovich:
echo   http://msevents.microsoft.com/CUI/WebCastEventDetails.aspx?EventID=1032298075
echo.
echo How to read small memory dump files:
echo   http://support.microsoft.com/kb/315263
echo.
echo How to Use Driver Verifier to Troubleshoot Windows Drivers:
echo   http://support.microsoft.com/Default.aspx?kbid=244617
goto :EOF

::==========================
:: End of script
::==========================
Вложения
kdfe_edit_by_DesignerMix.rar
Отредактированный скрипт KDFE (должен работать сразу)
(2.6 КБ) 763 скачивания


Belyj
Постоянный пользователь
Сообщения: 112
Зарегистрирован: 09 июн 2014, 21:16
Есть ответ: 6
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение Belyj » 09 июн 2014, 22:28

Весьма смелое название темы. А между тем сия тема очень обширна. Лучше взять за правило в таких ситуациях при любом раскладе всегда проверять память и винт, причём сначала непосредственно сами разъёмы/шлейфы а уж потом и тесты. Ибо ни одна софтинка никогда не покажет, что окислен контакт или пылинка в разъём попала. А покажет она в любом случае на какой либо файл/процесс/драйвер и придётся долгий и тернистый путь :D

Аватара пользователя

Автор темы
DesignerMix
Администратор
Администратор
Сообщения: 4830
Зарегистрирован: 25 апр 2014, 10:51
Есть ответ: 185
Откуда: Белгород
Контактная информация:
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение DesignerMix » 09 июн 2014, 22:45

Belyj, если грамотно проводить диагностику программно, при этом анализируя дампы памяти, заглядывая в журнал событий Windows и делая правильные выводы, то можно довольно быстро понять в чем именно проблема.

С тем что на опере часто окисляются контакты согласен, но вы-же сами сказали что тема обширна и поэтому сразу бросаться в поиск аппаратных неисправностей наверное не стоит. Тем более те люди которые смотрели это видео в большинстве своем не имеют опыта в разборе компьютера не говоря уже о извлечении отдельных его частей и было-бы опрометчиво им это советовать т.к. если они не исправят проблему, а сделают только хуже будет не очень хорошо.


Belyj
Постоянный пользователь
Сообщения: 112
Зарегистрирован: 09 июн 2014, 21:16
Есть ответ: 6
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение Belyj » 11 июн 2014, 00:03

Согласен. Но далеко не всё можно починить программными методами. Синие экраны в большинстве своём как раз таки возникают из-за неполадок с памятью и жестким диском. А если не лазить внутрь компьютера, то как же тогда учиться ремонту. :D Не думаю что требуются какие-то особые навыки, чтоб достать планочку и поводить по ней ластиком, народ нынче продвинутый пошел.
Сам в таких случаях предпочитаю сперва исключать такие вот проблемы, чем по пять раз гонять тесты, это же всё уйму времени отнимает. Анализ дампов штука,конечно хорошая, сам предпочитаю упомянутую выше bluescreen view, но на практике до анализа дампа почти никогда не доходит.


banzay_man
Новичок
Сообщения: 6
Зарегистрирован: 12 июн 2014, 07:37
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение banzay_man » 12 июн 2014, 07:59

Всем привет. У меня стоит ОС Windows 8.1 и появляется синий экран при загрузке. Я сделал все как описано чтоб информация об ошибке сохранилась в .dmp файле для следующего анализа, но C:\Windows\Minidump папка пуста. Как сделать чтоб информация сохранилась в Minidump папке?


Belyj
Постоянный пользователь
Сообщения: 112
Зарегистрирован: 09 июн 2014, 21:16
Есть ответ: 6
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение Belyj » 12 июн 2014, 22:41

Всегда при загрузке в одном и том же месте? После чего это произошло. Ноутбук или стационар? В win 8 экран смерти не очень информативен. Какую-то ошибку пишет?

Аватара пользователя

Автор темы
DesignerMix
Администратор
Администратор
Сообщения: 4830
Зарегистрирован: 25 апр 2014, 10:51
Есть ответ: 185
Откуда: Белгород
Контактная информация:
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение DesignerMix » 12 июн 2014, 23:01

banzay_man писал(а):Всем привет. У меня стоит ОС Windows 8.1 и появляется синий экран при загрузке. Я сделал все как описано чтоб информация об ошибке сохранилась в .dmp файле для следующего анализа, но C:\Windows\Minidump папка пуста. Как сделать чтоб информация сохранилась в Minidump папке?
Нажмите комбинацию клавиш Win+Pause Break в открывшемся окне выберите "Дополнительные параметры системы", далее в пункте "Загрузка и восстановление" нажмите кнопку "Параметры" и проверьте чтобы в пункте "Отказ системы" были такие параметры:
Загрузка и восстановление.PNG


banzay_man
Новичок
Сообщения: 6
Зарегистрирован: 12 июн 2014, 07:37
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение banzay_man » 13 июн 2014, 07:13

я все делаю как показано но система не сохраняет в minidump папке ничего :(

Аватара пользователя

Автор темы
DesignerMix
Администратор
Администратор
Сообщения: 4830
Зарегистрирован: 25 апр 2014, 10:51
Есть ответ: 185
Откуда: Белгород
Контактная информация:
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение DesignerMix » 13 июн 2014, 10:26

banzay_man писал(а):я все делаю как показано но система не сохраняет в minidump папке ничего :(
Ладно, тогда проверьте что-бы был включен файл подкачки: Нажмите комбинацию клавиш Win+Pause Break в открывшемся окне выберите "Дополнительные параметры системы" далее как на картинке:
Свойства системы, параметры быстродействия, виртуальная память.jpg
Если файл подкачки у вас тоже был включен, попробуйте вручную создать папку Minidump (путь в итоге должен быть таким "Имя_диска_с_ОС:\Windows\Minidump").

Если ничего не поможет и после появления синего экрана дамп так и не появиться сделайте следующее:

Если вы уже вошли в систему:
  • Прокрутите от правой границы экрана и затем последовательно коснитесь элементов Параметры и Изменить параметры компьютера. (Если вы используете мышь, переместите указатель в верхний правый угол экрана, затем вниз и последовательно щелкните Параметры и Изменить параметры компьютера.)
  • В разделе Параметры компьютера выберите Обновление и восстановление.
  • Теперь выберете Восстановление
  • В разделе Особые варианты загрузки выберете Перезагрузить сейчас
  • Далее последовательно зайдите - Диагностика -> Дополнительные параметры -> Параметры загрузки -> Перезагрузить -> При запросе нажмите клавишу F9, таким образом вы отключите автоматическую перезагрузку при отказе системы.
И когда синий экран появится снова компьютер не перезагрузится, таким образом вы сможете переписать код ошибки. Напишите его сюда и будем думать в чем проблема.


banzay_man
Новичок
Сообщения: 6
Зарегистрирован: 12 июн 2014, 07:37
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение banzay_man » 15 июн 2014, 08:59

он так и не создается. когда виндоус питается загружаться зависает и показывает синий экран с грустным смайликом и там написано SYSTEM_THREAD_EXCEPTION_NOT_HANDLED, но код ошибки не написанно.

Аватара пользователя

Автор темы
DesignerMix
Администратор
Администратор
Сообщения: 4830
Зарегистрирован: 25 апр 2014, 10:51
Есть ответ: 185
Откуда: Белгород
Контактная информация:
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение DesignerMix » 15 июн 2014, 12:24

banzay_man писал(а):он так и не создается. когда виндоус питается загружаться зависает и показывает синий экран с грустным смайликом и там написано SYSTEM_THREAD_EXCEPTION_NOT_HANDLED, но код ошибки не написанно.
Вам выше задавали вопрос, но вы так и не ответили... У вас ноутбук или стационарный компьютер? Если ноут, напишите его модель.

По поводу ошибки SYSTEM_THREAD_EXCEPTION_NOT_HANDLED:
- Попробуйте отключить все USB-устройства из портов (кроме клавиатуры и мышки , если они USB);
- Если не помогло, попробуйте восстановить BIOS на значения по умолчанию. Для этого зайдите в BIOS и в пункте "Exit" выберите "load optimal defaults" и затем нажмите F10, таким образом будут восстановлены значения по умолчанию для BIOS материнской платы:
Инструкция по входу в BIOS
Шаг 1. Перезагружаем компьютер
- Включите компьютер, либо начните перезагрузку компьютера.

Шаг 2. Входим в BIOS
- Нажмите клавишу Del сразу после включения компьютера (до начала загрузки операционной системы), лучше несколько раз.
- В момент включения компьютера сначала отображаются служебные сообщения от компьютера. Обычно они быстро исчезают, но можно успеть прочитать надпись "press <Delete> for setup" - вот тут-то и надо нажимать. Вместо этой фразы или клавиши Del может быть написана другая, тогда нажимайте ее.

Что делать, если не сработало?
- Если у вас ноутбук или "брендовый" компьютер, нажатие Del может не сработать, в этом случае попробуйте клавишу F2.
- Следует заметить, что каждый сборщик/производитель компьютера волен использовать любые клавиши для входа пользователя в BIOS. Однако клавиша (или же комбинация клавиш), как правило, указывается на экране сразу после включения компьютера. Чтобы задержать изображение на экране следует пользоваться клавишей Pause (верхний ряд клавиатуры).
- Del и F2 встречаются чаще всего, однако в некоторых моделях компьютеров возможны различные варианты входа в BIOS - это могут быть клавиши F8, F10, Esc.
- Если ничего из вышеперечисленного не помогло, попробуйте переключить режим работы жесткого диска в BIOS - на "Compateble IDE" если он стоит на "AHCI", либо наоборот на "AHCI" если он стоял на "Compateble IDE". Если это не изменит ситуацию верните значение на то, которое было изначально.

- Ну и наконец если все вышеперечисленное не принесет результата, нужно проверить жесткий диск на ошибки. К примеру воспользовавшись утилитой HDD Regenerator


banzay_man
Новичок
Сообщения: 6
Зарегистрирован: 12 июн 2014, 07:37
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение banzay_man » 16 июн 2014, 10:03

ноутбук HP ProBook 6550b, о можно какнибуть так сделат что синий экран показывала в стиле XP где ошибка видно и все такое?


Belyj
Постоянный пользователь
Сообщения: 112
Зарегистрирован: 09 июн 2014, 21:16
Есть ответ: 6
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение Belyj » 16 июн 2014, 22:15

Как в хр сделать не получится.
Смею предположить что проблема возникла после установки драйвера, либо обновления. Пока вы нам не расскажите подробно, мы не сможем вам помочь. Заданные мной вопросы вы проигнорировали. Система хоть иногда загружается? Безопасный режим работает? Может получится, удерживая shift, нажать кнопочку перезагрузка и откатить системку?

Аватара пользователя

Автор темы
DesignerMix
Администратор
Администратор
Сообщения: 4830
Зарегистрирован: 25 апр 2014, 10:51
Есть ответ: 185
Откуда: Белгород
Контактная информация:
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение DesignerMix » 16 июн 2014, 22:50

Belyj писал(а):Заданные мной вопросы вы проигнорировали.
Ага, и предложенные мной варианты решения тоже... как-то не хочется помогать если человек каждый раз задает какой-то новый вопрос полностью игнорируя ответы на предыдущий.


banzay_man
Новичок
Сообщения: 6
Зарегистрирован: 12 июн 2014, 07:37
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение banzay_man » 17 июн 2014, 03:32

ни кто ничего не игнорировал, не ваши вопросы и не предложенные вами варианты. потому задаю новый вопрос что, делаю как пишите но все ровно не помогает, иначе написал бы что решено. проблема появилось после обновления и в безопасный режим загружается нормально.

Аватара пользователя

Автор темы
DesignerMix
Администратор
Администратор
Сообщения: 4830
Зарегистрирован: 25 апр 2014, 10:51
Есть ответ: 185
Откуда: Белгород
Контактная информация:
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение DesignerMix » 17 июн 2014, 08:07

banzay_man писал(а):ни кто ничего не игнорировал, не ваши вопросы и не предложенные вами варианты. потому задаю новый вопрос что, делаю как пишите но все ровно не помогает, иначе написал бы что решено. проблема появилось после обновления и в безопасный режим загружается нормально.
Тогда вам необходимо просто выполнить откат на предыдущую точку восстановления. Точки восстановления автоматически создаются перед установкой обновлений Windows.

Чтобы это сделать загрузитесь в безопасном режиме и сделайте следующее:
- Нажмите комбинацию клавиш Win+R и в открывшемся окне введите rstrui затем нажмите Enter.
- В открывшемся окне просто следуя инструкциям мастера восстановления системы выберите контрольную точку ориентируйтесь по дате создания точки и описанию. Что-бы узнать какие программы будут затронуты при откате нажмите соответствующую кнопку в мастере.

После восстановления, если проблема была только в установке обновления, система должна загрузиться корректно.


banzay_man
Новичок
Сообщения: 6
Зарегистрирован: 12 июн 2014, 07:37
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение banzay_man » 19 июн 2014, 08:33

ладно, спасибо большое за оказанную помощь.


Slaverok
Новичок
Сообщения: 12
Зарегистрирован: 12 июн 2014, 02:11
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение Slaverok » 04 июл 2014, 21:56

Здравствуйте.

1. Зайдите на сайт производителя ноутбука и скачайте все последние версии драйверов для вашей модели.
2. Выполните обновление BIOS.
3. Загрузите ПК в режим чистой загрузки и повторите попытку обновления.
4. Так же возможно что создаются дампы памяти, проверьте есть ли они.
'
http://answers.microsoft.com/ru-ru/wind ... c67671a7ed


Alex
Интересующийся
Сообщения: 42
Зарегистрирован: 21 июн 2014, 11:16
Есть ответ: 3
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение Alex » 16 июл 2014, 18:27

Полагаю код ошибки отмел бы 50-80% неверных попыток разобраться. 0x000000???


Vladiclavgj
Новичок
Сообщения: 1
Зарегистрирован: 23 авг 2014, 14:20
Статус: Не в сети

Re: Исправляем синий экран смерти (BSOD). Windows Debugging

Сообщение Vladiclavgj » 23 авг 2014, 14:25

Здраствуйте. Я посмотрел ваше видео по поводу Синего экрана смерти.Сделал все как в видео вплоть до kdfe и переделал его.Но когда я выбираю dump file(он у меня 1)он не выдает ничего. Не подскажете что делать? Экран появляется при просмотре видео в вк и (т.п).Win 8.1,ошибка DPC_Watchdog_Violation. Архив прикреплен всей папкой.
Вложения
Minidump.rar
Minidump
(70.21 КБ) 91 скачивание

Ответить

Вернуться в «Windows»

Кто сейчас на конференции

Сейчас этот форум просматривают: нет зарегистрированных пользователей и 1 гость